mirror of
https://github.com/ipxe/ipxe
synced 2025-12-26 17:42:47 +03:00
ca319873bf
Our use of --gc-sections causes the linker to discard the symbols defined by FILE_LICENCE(), meaning that the resulting licence determination is incomplete. We must use the KEEP() directive in the linker script to force the linker to not discard the licence symbols. Using KEEP(*(COMMON)) would be undesirable, since there are some symbols in COMMON which we may wish to discard. Fix by placing symbols defined by PROVIDE_SYMBOL() (which is used by FILE_LICENCE()) into a special ".provided" section, which we then mark with KEEP(). All such symbols are zero-length, so there is no cost in terms of the final binary size. Since the symbols are no longer in COMMON, the linker will reject symbols with the same name coming from multiple objects. We therefore append the object name to the licence symbol, to ensure that it is unique. Reported-by: Marin Hannache <git@mareo.fr> Signed-off-by: Michael Brown <mcb30@ipxe.org>
111 lines
1.6 KiB
Plaintext
111 lines
1.6 KiB
Plaintext
/* -*- sh -*- */
|
|
|
|
/*
|
|
* Linker script for EFI images
|
|
*
|
|
*/
|
|
|
|
SECTIONS {
|
|
|
|
/* The file starts at a virtual address of zero, and sections are
|
|
* contiguous. Each section is aligned to at least _max_align,
|
|
* which defaults to 32. Load addresses are equal to virtual
|
|
* addresses.
|
|
*/
|
|
|
|
_max_align = 32;
|
|
|
|
/* Allow plenty of space for file headers */
|
|
. = 0x1000;
|
|
|
|
/*
|
|
* The text section
|
|
*
|
|
*/
|
|
|
|
. = ALIGN ( _max_align );
|
|
.text : {
|
|
_text = .;
|
|
*(.text)
|
|
*(.text.*)
|
|
_etext = .;
|
|
}
|
|
|
|
/*
|
|
* The rodata section
|
|
*
|
|
*/
|
|
|
|
. = ALIGN ( _max_align );
|
|
.rodata : {
|
|
_rodata = .;
|
|
*(.rodata)
|
|
*(.rodata.*)
|
|
_erodata = .;
|
|
}
|
|
|
|
/*
|
|
* The data section
|
|
*
|
|
*/
|
|
|
|
. = ALIGN ( _max_align );
|
|
.data : {
|
|
_data = .;
|
|
*(.data)
|
|
*(.data.*)
|
|
KEEP(*(SORT(.tbl.*))) /* Various tables. See include/tables.h */
|
|
KEEP(*(.provided))
|
|
KEEP(*(.provided.*))
|
|
_edata = .;
|
|
}
|
|
|
|
/*
|
|
* The bss section
|
|
*
|
|
*/
|
|
|
|
. = ALIGN ( _max_align );
|
|
.bss : {
|
|
_bss = .;
|
|
*(.bss)
|
|
*(.bss.*)
|
|
*(COMMON)
|
|
_ebss = .;
|
|
}
|
|
|
|
/*
|
|
* Weak symbols that need zero values if not otherwise defined
|
|
*
|
|
*/
|
|
|
|
.weak 0x0 : {
|
|
_weak = .;
|
|
*(.weak)
|
|
*(.weak.*)
|
|
_eweak = .;
|
|
}
|
|
_assert = ASSERT ( ( _weak == _eweak ), ".weak is non-zero length" );
|
|
|
|
/*
|
|
* Dispose of the comment and note sections to make the link map
|
|
* easier to read
|
|
*
|
|
*/
|
|
|
|
/DISCARD/ : {
|
|
*(.comment)
|
|
*(.comment.*)
|
|
*(.note)
|
|
*(.note.*)
|
|
*(.eh_frame)
|
|
*(.eh_frame.*)
|
|
*(.rel)
|
|
*(.rel.*)
|
|
*(.einfo)
|
|
*(.einfo.*)
|
|
*(.discard)
|
|
*(.discard.*)
|
|
}
|
|
}
|